[아두이노] 주기적인 데이터 처리

《 주기적인 데이터 처리 》

 

[ 디지털 및 아날로그 데이터 처리 ]

	입력	출력
디지털	int pin_no = 13; pinMode(pin_no, INPUT); boolean value = digitalRead(pin_no);	int pin_no = 13; boolean value = HIGH; pinMode(pin_no, OUTPUT); digitalWrite(pin_no, value);
아날로그	int pin_no = A0; pinMode(pin_no, INPUT); int value = analogRead(pin_no);	int pin_no = 3; int dutyCycle = 128; pinMode(pin_no, OUTPUT); analogWrite(pin_no, dutyCycle);

 

 

[ delay() 함수 ]

- 지정한 시간만큼 실행을 대기하는 함수

- 밀리초 단위의 지연시간 사용 가능

- delay() 함수 실행 중엔 프로그램이 일시 중단

 

 

delay 함수를 사용하여 버튼과 LED 제어 예제

// C++ code
// delay() 함수를 사용하여 버튼과 LED 제어

int pin_button = 2;
int pin_led_1 = 12;
int pin_led_2 = 8;
boolean LED_state_1 = false;  // 13번핀의 LED 점멸 여부 판단
boolean LED_state_2 = false;  // 9번핀의 LED 점멸 여부 판단

void setup()
{
  Serial.begin(9600);
  
  pinMode(pin_button, INPUT);
  
  pinMode(pin_led_1, OUTPUT);
  digitalWrite(pin_led_1, LED_state_1);
  
  pinMode(pin_led_2, OUTPUT);
  digitalWrite(pin_led_2, LED_state_2);
}

void loop()
{
  digitalWrite(pin_led_1, LED_state_1);
  delay(1000);
  LED_state_1 = !LED_state_1;
  
  if(digitalRead(pin_button)){
  	LED_state_2 = !LED_state_2;
    digitalWrite(pin_led_2, LED_state_2);
  } 
}

 - 프로그램을 실행 시키면 loop() 함수의 LED_state_1 = !LED_state_1; 코드에 의해 12번 pin과 연결된 LED가 

   점멸하는 것을 확인 가능

 - 버튼을 누르면 8번 pin과 연결된 LED가 점등하게 되고 다시 버튼을 누르면 소등할 것이라고 생각하지만

   loop() 함수 내의 delay(1000); 코드가 실행중에 있어 버튼이 눌린 즉시 8번 pin의 LED의 상태가 변경되지 않음.

 - 이러한 즉각적 반응이 필요한 경우에는 delay()함수 대신 millis() 함수를 사용해야함.

 

 

[ millis() 함수 ]

 - 현재 실행 중인 스케치가 시작된 이후의 경과 시간을 밀리초 단위로 반환

 - delay() 함수가 실행되는 도중에는 프로그램이 일시적으로 중단되기 때문에 상태의 주기적인 검사가 불가능

 - 이를 보완하는 방식이 polling 방식임.

 - miilis() 함수는 현재까지의 실행 시간을 즉시 반환하므로 즉시 다른 작업 수행 가능

 

 

delay() 함수를 사용하여 블링크 테스트 예제

// C++ code
// delay() 함수를 사용하여 블링크 테스트
// 1초 간격으로 LED 점멸 

int pin_LED = 9;
boolean LED_state = false;

void setup()
{
  Serial.begin(9600);
  pinMode(pin_LED, OUTPUT);
  digitalWrite(pin_LED, LED_state);
}

void loop()
{
  LED_state = !LED_state;
  digitalWrite(pin_LED, LED_state);
  delay(1000);
}

 

 

millis() 함수를 사용하여 블링크 테스트 예제

// C++ code
// millis() 함수를 사용하여 블링크 테스트

int pin_LED = 9;
boolean LED_state = false;
unsigned long time_previous;
unsigned long time_current;
unsigned long count = 0;	// loop 함수 실행 횟수

void setup()
{
  Serial.begin(9600);
  pinMode(pin_LED, OUTPUT);
  digitalWrite(pin_LED, LED_state);
  
  time_previous = millis();	// 시작 시간 측정
}

void loop()
{
  time_current = millis();	// 현재 시간
  count++;
  
  // 1초 이상 시간이 경과한 경우
  if(time_current - time_previous >= 1000){
    time_previous = time_current;	// 시작 시간 갱신
    
    LED_state = !LED_state;
    digitalWrite(pin_LED, LED_state);
    
    Serial.println(count);			// 1초에 실행되는 loop 함수 횟수
    count = 0;
  }
}

 

 

millis 함수를 사용하여 버튼과 LED 제어 예제

// C++ code
// millis() 함수를 사용하여 버튼과 LED 제어
// millis() 함수를 통해 버튼이 눌러지는 즉시 LED_state의 값 변경 가능

int pin_button = 2;
int pin_led_1 = 12;
int pin_led_2 = 8;
boolean LED_state_1 = false;  // 13번핀의 LED 점멸 여부 판단
boolean LED_state_2 = false;  // 9번핀의 LED 점멸 여부 판단
unsigned long time_previous;
unsigned long time_current;

void setup()
{
  Serial.begin(9600);
  pinMode(pin_button, INPUT);
  
  pinMode(pin_led_1, OUTPUT);
  digitalWrite(pin_led_1, LED_state_1);
  
  pinMode(pin_led_2, OUTPUT);
  digitalWrite(pin_led_2, LED_state_2);
  
  time_previous = millis();		// 시작 시간
}

void loop()
{
  time_current = millis();		// 현재 시간
  if(time_current - time_previous >= 1000){
    time_previous = time_current;	// 시작 시간 초기화
    
    LED_state_1 = !LED_state_1;
    digitalWrite(pin_led_1, LED_state_1);
  }
  
  if(digitalRead(pin_button)){
    LED_state_2 = !LED_state_2;
    
    digitalWrite(pin_led_2, LED_state_2);
  	delay(100);
  }
}

- 위의 delay() 함수를 사용하여 제어할 때와 달리 millis() 함수를 사용하면 버튼을 누름과 동시에 8번 pin과 연결된

  LED가 점등, 소등하는 것을 확인 가능

 

 

delay 함수를 사용하여 버튼과 LED 제어(버튼 상태 변화 검사) 예제

// C++ code
// millis() 함수를 사용하여 버튼과 LED 제어
// 버튼을 누르는 순간에만 LED_2 상태 변경

int pin_button = 2;
int pin_led_1 = 12;
int pin_led_2 = 8;
boolean LED_state_1 = false;  // 13번핀의 LED 점멸 여부 판단
boolean LED_state_2 = false;  // 9번핀의 LED 점멸 여부 판단
unsigned long time_previous;
unsigned long time_current;
boolean button_state_previous=false;	// 버튼의 초기 값
boolean button_state_current;			// 버튼의 현재 상태

void setup()
{
  Serial.begin(9600);
  pinMode(pin_button, INPUT);
  
  pinMode(pin_led_1, OUTPUT);
  digitalWrite(pin_led_1, LED_state_1);
  
  pinMode(pin_led_2, OUTPUT);
  digitalWrite(pin_led_2, LED_state_2);
  
  time_previous = millis();		// 시작 시간
}

void loop()
{
  time_current = millis();			// 현재 시간
  if(time_current - time_previous >= 1000){
    time_previous = time_current;	// 시작 시간 초기화
    
    LED_state_1 = !LED_state_1;
    digitalWrite(pin_led_1, LED_state_1);
  }
  
  button_state_current = digitalRead(pin_button);
  if(button_state_current){
    if(button_state_previous == false){
      button_state_previous = true;
      LED_state_2 = !LED_state_2;	// 8번 pin LED의 상태 변경
      digitalWrite(pin_led_2, LED_state_2);
    }
  }
  else
    button_state_previous = false;
  
  Serial.println(button_state_previous);
  delay(1000);
}

- 버튼이 눌러지는 순간에만 pin_led_2의 상태가 반전되는 코드

 

 

 

[ 가변저항으로 블링크 속도 제어 ]

 - millis() 함수를 통해 사용자의 입력에 즉각적으로 반응하는 것을 이용하면

   가변저항의 값 변화를 통해 블링크 속도를 조절 가능

 

[ map() 함수 ]

- 가변저항의 아날로그 입력값(0~1023)을 PWM 값(0~255)으로 출력하고자 할 때

  입력값의 범위를 출력값의 범위로 맞추어야하는데 이를 매핑이라함.

[형식]

 - long map(value, fromLow, fromHigh, toLow, toHigh)

[매개변수]

 - value : maping 하고자 하는 값

 - fromLow : 현재 범위의 하한

 - fromHigh : 현재 범위의 상한

 - toLow : 목표 범위 값의 하한

 - toHigh : 목포 범위 값의 상한

[반환]

 - 지정한 범위로 maping된 값

 

 

가변저항으로 블링크 속도 제어 예제

// C++ code
// 가변저항의 0~1023 사이 값을 500~1500 ms 단위로 변환하여 블링크 속도 제어
// 가변저항 값과 점멸 간격 사이 변환을 위해 map() 함수 사용

int pin_led = 13;
unsigned long time_previous;
unsigned long time_current;
unsigned long interval = 1000;	// 점멸 간격
boolean LED_state = false;

void setup()
{
  Serial.begin(9600);
  pinMode(pin_led, OUTPUT);
  digitalWrite(pin_led, LED_state);
  
  pinMode(A0, INPUT);
  
  time_previous = millis();
}

void loop()
{
  time_current = millis();
  
  if(time_current - time_previous >= interval){
    Serial.print("Current interval is ");
    Serial.print(interval);
    Serial.println("ms");
    
    time_previous = time_current;
    
    LED_state = !LED_state;
    digitalWrite(pin_led, LED_state);
  } 
  int adc = analogRead(A0);
  // A0로부터 읽어온 아날로그 값(0~1023)을 
  // ms 단위(500~1500/0.5s ~ 1.5s)로 변환하여 블링크 속도 제어
  interval = map(adc, 0, 1023, 500, 1500);
}