[아두이노] 텍스트 LCD

《 텍스트 LCD 》

 

[ 텍스트 LCD ]

 - 액정(Liquid Crystal)을 이용하여 고정된 위치에 문자 단위의 영문자, 숫자 등을 표현 가능

 - 그래픽이나 한글 표시에 적합하지 않고, 표시할 수 있는 문자의 수가 한정적임.

 - 대체로 16(행) x 2(열) = 32 글자를 표시할 수 있는 텍스트 LCD가 주로 사용됨.

 

[ 16개의 연결 핀을 가진 텍스트 LCD의 핀의 구성 ]

 - 전원 관련 핀 5개(Vss, Vcc, Vo, LED+, LED-)

 - 제어 신호 핀 3개(Rs, R/W, E)

 - 데이터 신호 핀 8개(DB0 ~ DB7)

    - 4비트 모드 : 4개의 데이터 핀만 사용

    - 8비트 모드 : 8개의 데이터 핀 모두 사용

 

[ 텍스트 LCD의 제어 신호 핀 ]

제어 신호 핀	설명
RS (Register Select)	- 텍스트 LCD를 제어하기 위해 제어 레스지터&데이터 레지스터 사용 - RS 신호는 명령을 담고 있는 레지스터(RS=LOW)와 데이터를 담고있는 레지스터(RS=HIGH)    중 하나를 선택하기 위해 사용
R/W (Read/Write)	- 읽기 및 쓰기 (R/W = HiGH || LOW) 모드 선택을 위해 사용
E (Enable)	- 하강 엣지(falling edge)에서 LCD 드라이버가 처리를 시작하도록 지시하기 위한 신호로 사용

  

[ 텍스트 LCD의 16개 연결핀 구성표 ]

텍스트 LCD 연결핀

 

 

 

《 텍스트 LCD 연결 회로 사용 (16핀 / 4비트 모드) 》

16핀 텍스트 LCD 연결 회로

 - 텍스트 LCD를 쓰기 용도로만 사용하므로 R/W 제어 신호핀 GND 연결

 

16핀 텍스트 LCD 연결 회로도

 

[ LiquidCrystal 라이브러리 ]

 - 16핀 텍스트 LCD 사용시 이용

 - 아두이노 IDE 내장 라이브러리 LiquidCrystal 사용, 4비트/8비트 모드 지원

- 아두이노 IDE에서 '스케치 -> 라이브러리 포함하기 -> LiquidCrystal' 선택하여 헤더파일 추가

[ LiquidCrystal 라이브러리 주요 함수 ]

Function	Description	Syntax	Parameters
LiquidCrystal( )	- LiquidCrystal 타입의 객체 생성 - 4개, 8개의 데이터 라인을 사용하여 제어 - 4비트 모드 [ DB0 ~ DB3 핀 번호 생략 ] - 8비트 모드 [  DB0 ~ DB7 핀 모두 연결 ]	LiquidCrystal(rs, enable, d4~d7) LiquidCrystal(rs, rw, enable, d4~d7) LiquidCrystal(rs, enable, d0~d7) LuquidCrystal(rs, rw, enable, d0~d7)	rs - LCD의 RS 핀에    연결된 핀 번호 rw[선택] - LCD의 RW 핀에    연결된 핀 번호 enable - LCD의 enable 핀에   연결된 핀번호 d0~d7 - LCD의 해당 데이터   핀에 연결된 핀 번호
begin( )	- LCD 화면에 대한 인터페이스 초기화 - 디스플레이의 치수(행 열) 지정 - 다른 명령보다 우선 호출	lcd.begin(cols, rows)	cols - 행의 개수 rows - 열의 개수
clear( )	- LCD 화면을 지우고, 커서 위치 초기화	lcd.clear() lcd.clear()	lcd - LiquidCrystal 타입   객체
setCursor( )	- LCD 커서 위치 설정 (표시할 텍스트 위치)	lcd.setCursor(col, row)	col - 행 위치 (0~1) rows - 열 위치 (0~15)
write()	- LCD에 문자 출력	lcd.write(data)	data - 표시할 문자
print()	- LCD에 텍스트 출력	lcd.print(data) lcd.print(data, BASE)	data  - 출력할 데이터 - char, byte, int, long   or string BASE[선택]  - 숫자 출력 기준 - BIN, DEC, OCT, HEX

 

[ (1) 텍스트 LCD 기본 출력 예제]

// C++ code
// (1) 텍스트 LCD 기본 출력 예제
#include <LiquidCrystal.h>

// 핀 번호 (RS, E, DB4, DB5, DB6, DB7)
LiquidCrystal lcd(13, 12, 7, 6, 5, 4);	// lcd 객체 생성

void setup()
{
  Serial.begin(9600);
  lcd.begin(16, 2);		// lcd 객체 초기화

  lcd.setCursor(1, 0);
  lcd.print("Hellow World!!");
  lcd.setCursor(1, 1);
  lcd.print(" -Coding Gym- ");  
}

void loop(){
}

(1) 텍스트 LCD 기본 출력 예제

 

[ (2) 텍스트 LCD 기본 출력 예제]

// C++ code
// (2) 텍스트 LCD 기본 출력 예제
// setCursor() 함수를 사용하여 2행으로 숫자 출력
#include <LiquidCrystal.h>

// 핀 번호 (RS, E, DB4, DB5, DB6, DB7)
LiquidCrystal lcd(13, 12, 7, 6, 5, 4);	// LCD 연결

void setup()
{
  Serial.begin(9600);
  lcd.begin(16, 2);		// LCD 초기화
  
  lcd.setCursor(0, 0);	// 커서 위치 0행 0열
  lcd.write('1');
  lcd.setCursor(5, 0);	// 커서 위치 5행 0열
  lcd.write('2');
  
  lcd.setCursor(0, 1);	// 커서 위치 0행 1열
  lcd.write('3');
  lcd.setCursor(5, 1);	// 커서 위치 5행 1열
  lcd.write('4');
}

void loop(){
}

 

(2) 텍스트 LCD 기본 출력 예제

 

[ (3) 텍스트 LCD 기본 출력 예제]

// C++ code
// 난수 생성을 통해 랜덤 대문자 랜덤 위치 출력
// 난수가 0일 경우 공백문자 출력으로 대체
#include <LiquidCrystal.h>

// 핀 번호 (RS, E, DB4, DB5, DB6, DB7)
LiquidCrystal lcd(13, 12, 7, 6, 5, 4);	// LCD 연결

void setup()
{
  Serial.begin(9600);
  lcd.begin(16, 2);		// LCD 초기화
  lcd.clear();			// LCD 디스플레이 초기화
  
  // 외부 회로가 연결되지 않은 아날로그 핀으로부터 무작위 값 입력받아 사용
  randomSeed(analogRead(A5));	// 난수 생성 초기화
}

void loop(){
  int row = random(0, 2);	// 커서의 행 난수(0-2) 생성
  int col = random(0, 17);	// 커서의 열 난수(0-17) 생성
  
  char ch = random(0, 27);	// 출력 문자 난수(아스키 코드 0-27 해당) 생성
  if(ch==0)					// ch값이 0일 경우 공백 출력
    ch = ' ';
  else 
    ch = ch + 'A'-1;		// 난수 값을 아스키코드 대문자로 변환
  
  lcd.setCursor(col, row);
  lcd.write(ch);
  
  Serial.println(String("(") + row + ", " + col + ")" + ch);
  delay(200);
}

(3) 텍스트 LCD 기본 출력 예제

시리얼 모니터 출력 결과

 

[ (4) 텍스트 LCD 기본 출력 예제]

// C++ code
// 사용자 정의 문자 정의 및 디스플레이 출력
#include <LiquidCrystal.h>

// 핀 번호 (RS, E, DB4, DB5, DB6, DB7)
LiquidCrystal lcd(13, 12, 7, 6, 5, 4);	// LCD 객체 생성

// 사용자 정의 문자 데이터(비트 사용)
byte user1[8] = {
  B00000, B10001, B00000, B00000, B10001, B01110, B00000, B00000
};
byte user2[8] = {
  B00000, B10001, B01010, B10001, B00000, B10001, B01110, B00000
};

void setup()
{
  Serial.begin(9600);
  lcd.createChar(1, user1);	// 사용자 정의 문자1 생성
  lcd.createChar(2, user2);	// 사용자 정의 문자2 생성
  lcd.begin(16, 2);
  lcd.clear();
  
  lcd.write(byte(1));
  lcd.setCursor(6, 0);
  lcd.write(byte(2));
}

void loop(){
}

(4) 텍스트 LCD 기본 출력 예제

 

 

 

《 텍스트 LCD 연결 회로 (I2C) 》

텍스트 LCD (I2C) 연결 회로

텍스트 LCD (I2C) 연결 회로도

 

[ LiquidCrystal_I2C 라이브러리 ]

 - I2C 통신 모듈 텍스트 LCD 사용시 이용

 - 아두이노 IDE 외부 라이브러리 LiquidCrystal_I2C 사용

↓공식 설치 링크 ↓

https://github.com/johnrickman/LiquidCrystal_I2C

GitHub - johnrickman/LiquidCrystal_I2C: LiquidCrystal Arduino library for the DFRobot I2C LCD displays

- 링크 접속 후 'Code -> Download ZIP' 클릭 시 라이브러리 압축 파일 다운

https://github.com/johnrickman/LiquidCrystal_I2C

 

- LiquidCrystal_I2C.zip 파일 압축 해제 후 폴더를

- '내 PC-> IDE 설치 디스크 -> Program Files(x86) -> Arduino -> libraries'에 저장

- 아두이노 IDE에서 '스케치 -> 라이브러리 포함하기 -> LiquidCrystal_I2C' 선택하여 헤더파일 추가

 

 

// C++ code
// 텍스트 LCD(I2C 통신 모듈) 주소 스캔 하기
#include <Wire.h>
#include <LiquidCrystal_I2C.h>

void setup(){
  Wire.begin();
  Serial.begin(9600);
  
  while(!Serial);
  Serial.println("\n<< I2C Scanner >>");
}

void loop(){
  byte error, address;
  int nDevices;
  
  nDevices = 0;
  for(address = 1; address<127; address++){
    Wire.beginTransmission(address);
    error = Wire.endTransmission();
    
    if(error == 0){
      Serial.print("I2C device address : 0x");
      if(address<16)
        Serial.print("0");
      Serial.print(address, HEX);
      Serial.println(" !");
      
      nDevices++;
    }
    else if(error == 4){
      Serial.print("Unknown error at address 0x");
      if(address<16)
        Serial.print("0");
      Serial.println(address, HEX);
    }
  }
  if(nDevices == 0)
    Serial.println("No I2C devices found\n");
  else
    Serial.println("done\n");
  
  delay(3000); 
}

주소 스캔 예제 시리얼 모니터 출력 결과

 

 

[ 텍스트 LCD 기본 출력 예제 [I2C 통신] ]

// C++ code
// 텍스트 LCD 기본 출력 예제 [I2C 통신 모듈]
#include <LiquidCrystal_I2C.h>

LiquidCrystal_I2C lcd(0x27, 16, 2);  // I2C 통신 lcd 객체 생성
void setup(){
  Serial.begin(9600);
  // lcd.init();	// lcd 초기화
  lcd.begin();      // lcd 초기화
  lcd.backlight();  // lcd backlight Turn On
  lcd.print(" -Coding Gym- ");
  delay(1000);
}

void loop(){
}

예제 실행 결과