[아두이노] 7세그먼트 표시 장치

[ 7세그먼트 표시 장치(7-segment display) ]

- 7개의 선분으로 숫자나 글자를 표시하기 위해 LED를 사용하여 만든 출력 장치

- 7개 선분에 소수점 표시를 위한 LED(dp)가 추가된 8개의 세그먼트들을 1바이트의 데이터로 제어 가능

- FND(Flexible Numeric Display)라고도 부름

- 표시 장치의 10개 핀 중 2개는 VCC/GND를 연결하는 공통 핀

- 나머지 8개의 핀은 해당 세그먼트를 제어하는 제어핀

// 0~9까지 숫자 표현을 위한 
// 세그먼트 a, b, c, d, e, f, g, dp의 패턴

byte patterns[] = {
    0xFC,	// 0b 1111 1100  ->  0
    0x60,	// 0b 0110 0000  ->  1
    0xDA,	// 0b 1101 1010  ->  2
    0xF2,	// 0b 1111 0010  ->  3
    0x66,	// 0b 0110 0110  ->  4
    0xB6,	// 0b 1011 0110  ->  5
    0xBE,	// 0b 1011 1110  ->  6
    0xE4,	// 0b 1110 0100  ->  7
    0xFE,	// 0b 1111 1110  ->  8
    0xE6,	// 0b 1110 0110  ->  9
 };

[ 4자리 7세그먼트 표시장치 ]

- 1자리 7세그먼트 표시 장치의 제어를 위해서는 8개의 제어선이 필요했음.

- 1자리 7세그먼트 표시 장치를 통해 네자리수의 숫자를 출력하고자 한다면

32개의 제어선이 필요함.

- 아두이노 우노는 최대 20개의 디지털 입출력 핀만을 제공하므로 불가능함.

- 이 때 4자리 세그먼트 장치의 경우는 1자리 세그먼트 장치와 다른 방식을 사용

- 인간 눈의 반응속도는 그렇게 빠르지 않기 때문에 순식간에 물건이 사라지는 경우

잠깐은 사라진 것을 인식하지 못함(잔상 효과)

- 이를 활용하여 4자리 7세그먼트 장치에서 한번에 한자리 수를 표시하고 빠른 속도로

자리수를 바꾸어 표시하는 것을 반복한다면 잔상효과에 의해 4자리 숫자가 표시되는 것으로

보이게 된다.

- 잔상 효과를 이용하는 4자리 7세그먼트 표시 장치는 32개가 아닌 12개의 핀만으로 작동 가능

	1자리 7세그먼트 표시 장치	4자리 7세그먼트 표시 장치
출력	1자리 숫자 표현 가능	4자리 숫자 표현 가능
핀 사용	공통핀 8개 (a, b, c, d, e, f, g, dp)
핀 사용		4개의 자리 선택핀 (각 자릿수 선택) Digit 1, Digit 2, Digit 3, Digit 4

- (A) 그림을 보면 12, 9, 8, 6핀은 자리 선택핀으로 사용되고 있음

- 8개의 세그먼트를 제어하는 핀은 각 자리에서 공통으로 사용 중

- 해당 그림에서는 공통 음극 방식으로 회로를 구성하고 있으므로,

12번 핀에 LOW 값을 할당하고, 8개의 공통 제어핀에 0xFC(0)를 전달하면 첫번째 자리에 0 표시

이 때 다른 자릿수 선택핀에는 HIGH 값을 할당해야함

- 12, 9,핀에 HIGH, 8,6번핀에 LOW 값을 할당 할경우 0 0 x x 표시

4자리 7세그먼트 표시 장치에 숫자 한자리 표시

// C++ code
// 왼쪽에서 오른쪽으로 자리를 옮겨 가면서 숫자를 표시
// 각 자릿수마다 한번씩 표시한 후 0~9까지 숫자를 반복하여 표시

byte patterns[10] = {
    0xFC,	// 0b 1111 1100  ->  0
    0x60,	// 0b 0110 0000  ->  1
    0xDA,	// 0b 1101 1010  ->  2
    0xF2,	// 0b 1111 0010  ->  3
    0x66,	// 0b 0110 0110  ->  4
    0xB6,	// 0b 1011 0110  ->  5
    0xBE,	// 0b 1011 1110  ->  6
    0xE4,	// 0b 1110 0100  ->  7
    0xFE,	// 0b 1111 1110  ->  8
    0xE6,	// 0b 1110 0110  ->  9
};

// 자릿수 선택 핀
int digit_pin[4] = {5, 4, 3, 2};

// 세그먼트 모듈 연결 핀(a,b,c,d,e,f,g, dp)
int seg_pin[8] = {13, 12, 11, 10, 9, 8, 7, 6};

void setup()
{
  // 자릿수 선택 핀 출력 설정
  for(int i=0; i<4; i++)
    pinMode(digit_pin[i], OUTPUT);
  
  // 세그먼트 제어 핀 출력 설정
  for(int j=0; j<8; j++)
    pinMode(seg_pin[j], OUTPUT);
}

// 해당 자릿수에 숫자 하나를 표시하는 함수 
void show_digit(int pos, int num){
  
  // 인자로 받는 pos(자릿수) 위치의 핀만을 표시
  for(int i=0; i<4; i++){
    if(i+1 == pos)
      digitalWrite(digit_pin[i], LOW);
    else
      digitalWrite(digit_pin[i], HIGH);
  }
  
  // 세그먼트 모듈 핀 연결 핀(a,b,c,d,e,f,g, dp) 제어
  for(int j=0; j<8; j++){
    boolean on_off = bitRead(patterns[num], 7-j);
    digitalWrite(seg_pin[j], on_off);
  }
}

void loop()
{
  for(int n=0; n<10; n++){
    for(int pos=1; pos<=4; pos++){
      show_digit(pos, n);
      delay(200);
    }
  }
}

4자리 7세그먼트 표시 장치에 카운터 값 표시

// C++ code
// 4자리 7세그먼트 장치에 4자리 숫자 표시
// 0.1초 간격으로 숫자 증가 0~9999

byte patterns[10] = {
    0xFC,	// 0b 1111 1100  ->  0
    0x60,	// 0b 0110 0000  ->  1
    0xDA,	// 0b 1101 1010  ->  2
    0xF2,	// 0b 1111 0010  ->  3
    0x66,	// 0b 0110 0110  ->  4
    0xB6,	// 0b 1011 0110  ->  5
    0xBE,	// 0b 1011 1110  ->  6
    0xE4,	// 0b 1110 0100  ->  7
    0xFE,	// 0b 1111 1110  ->  8
    0xE6,	// 0b 1110 0110  ->  9
};

// 자릿수 선택 핀
int digit_pin[4] = {5, 4, 3, 2};
// 세그먼트 모듈 연결 핀(a,b,c,d,e,f,g, dp)
int seg_pin[8] = {13, 12, 11, 10, 9, 8, 7, 6};

int count = 0;
int SEGMENT_DELAY = 5;
unsigned long time_previous, time_current;

void setup()
{
  // 자릿수 선택 핀 출력 설정
  for(int i=0; i<4; i++)
    pinMode(digit_pin[i], OUTPUT);
  
  // 세그먼트 제어 핀 출력 설정
  for(int j=0; j<8; j++)
    pinMode(seg_pin[j], OUTPUT);
  
  time_previous = millis();
}

// 해당 자릿수에 숫자 하나를 표시하는 함수 
void show_digit(int pos, int num){
  
  // 인자로 받는 pos(자릿수) 위치의 핀만을 표시
  for(int i=0; i<4; i++){
    if(i+1 == pos)
      digitalWrite(digit_pin[i], LOW);
    else
      digitalWrite(digit_pin[i], HIGH);
  }
  
  // 세그먼트 모듈 핀 연결 핀(a,b,c,d,e,f,g, dp) 제어
  for(int j=0; j<8; j++){
    boolean on_off = bitRead(patterns[num], 7-j);
    digitalWrite(seg_pin[j], on_off);
  }
}

void show_4_digit(int n){
  
  n = n % 10000;		// 4자리로 제한
  int n4 = n / 1000;	// 천 자리
  n = n % 1000;
  int n3 = n / 100;		// 백 자리
  n = n % 100;
  int n2 = n / 10;		// 십 자리
  int n1 = n % 10;		// 한 자리

  show_digit(1, n4);
  delay(SEGMENT_DELAY);
  show_digit(2, n3);
  delay(SEGMENT_DELAY);
  show_digit(3, n2);
  delay(SEGMENT_DELAY);
  show_digit(4, n1);
  delay(SEGMENT_DELAY);
}

void loop()
{
  time_current = millis();
  
  if(time_current - time_previous >= 100){
    time_previous = time_current;
    
    count++;
  }
  
  show_4_digit(count);
}

4자리 7세그먼트 표시 장치에 가변저항 값 표시

// C++ code
// 가변저항 값을 아날로그 신호를 통해 세그먼트 장치에 표현

byte patterns[10] = {
    0xFC,	// 0b 1111 1100  ->  0
    0x60,	// 0b 0110 0000  ->  1
    0xDA,	// 0b 1101 1010  ->  2
    0xF2,	// 0b 1111 0010  ->  3
    0x66,	// 0b 0110 0110  ->  4
    0xB6,	// 0b 1011 0110  ->  5
    0xBE,	// 0b 1011 1110  ->  6
    0xE4,	// 0b 1110 0100  ->  7
    0xFE,	// 0b 1111 1110  ->  8
    0xE6,	// 0b 1110 0110  ->  9
};

// 자릿수 선택 핀
int digit_pin[4] = {5, 4, 3, 2};
// 세그먼트 모듈 연결 핀(a,b,c,d,e,f,g, dp)
int seg_pin[8] = {13, 12, 11, 10, 9, 8, 7, 6};

int SEGMENT_DELAY = 5;

void setup()
{
  // 자릿수 선택 핀 출력 설정
  for(int i=0; i<4; i++)
    pinMode(digit_pin[i], OUTPUT);
  
  // 세그먼트 제어 핀 출력 설정
  for(int j=0; j<8; j++)
    pinMode(seg_pin[j], OUTPUT);
}

// 해당 자릿수에 숫자 하나를 표시하는 함수 
void show_digit(int pos, int num){
  
  // 인자로 받는 pos(자릿수) 위치의 핀만을 표시
  for(int i=0; i<4; i++){
    if(i+1 == pos)
      digitalWrite(digit_pin[i], LOW);
    else
      digitalWrite(digit_pin[i], HIGH);
  }
  
  // 세그먼트 모듈 핀 연결 핀(a,b,c,d,e,f,g, dp) 제어
  for(int j=0; j<8; j++){
    boolean on_off = bitRead(patterns[num], 7-j);
    digitalWrite(seg_pin[j], on_off);
  }
}

void show_4_digit(int _n){
  
  int n = _n;
  
  n = n % 10000;		// 4자리로 제한
  int n4 = n / 1000;	// 천 자리
  n = n % 1000;
  int n3 = n / 100;		// 백 자리
  n = n % 100;
  int n2 = n / 10;		// 십 자리
  int n1 = n % 10;		// 한 자리

  if(_n > 999)
    show_digit(1, n4);
  delay(SEGMENT_DELAY);
  if(_n > 99)
    show_digit(2, n3);
  delay(SEGMENT_DELAY);
  if(_n > 9)
    show_digit(3, n2);
  delay(SEGMENT_DELAY);
  show_digit(4, n1);
  delay(SEGMENT_DELAY);
}

void loop()
{
  int reading = analogRead(A0);
  
  show_4_digit(reading);
}

4자리 7세그먼트 표시 장치에 시간 표시

// C++ code
// 4자리 숫자가 모두 표시
// 60초나 60분이 될 경우 0으로 되돌아간다.

byte patterns[10] = {
    0xFC,	// 0b 1111 1100  ->  0
    0x60,	// 0b 0110 0000  ->  1
    0xDA,	// 0b 1101 1010  ->  2
    0xF2,	// 0b 1111 0010  ->  3
    0x66,	// 0b 0110 0110  ->  4
    0xB6,	// 0b 1011 0110  ->  5
    0xBE,	// 0b 1011 1110  ->  6
    0xE4,	// 0b 1110 0100  ->  7
    0xFE,	// 0b 1111 1110  ->  8
    0xE6,	// 0b 1110 0110  ->  9
};

// 자릿수 선택 핀
int digit_pin[4] = {5, 4, 3, 2};
// 세그먼트 모듈 연결 핀(a,b,c,d,e,f,g, dp)
int seg_pin[8] = {13, 12, 11, 10, 9, 8, 7, 6};

int SEGMENT_DELAY = 5;
unsigned long time_previous, time_current;
int min=0, sec = 0;

void setup()
{
  // 자릿수 선택 핀 출력 설정
  for(int i=0; i<4; i++)
    pinMode(digit_pin[i], OUTPUT);
  
  // 세그먼트 제어 핀 출력 설정
  for(int j=0; j<8; j++)
    pinMode(seg_pin[j], OUTPUT);
  
  time_previous = millis();
}

// 해당 자릿수에 숫자 하나를 표시하는 함수 
void show_digit(int pos, int num){
  
  // 인자로 받는 pos(자릿수) 위치의 핀만을 표시
  for(int i=0; i<4; i++){
    if(i+1 == pos)
      digitalWrite(digit_pin[i], LOW);
    else
      digitalWrite(digit_pin[i], HIGH);
  }
  
  // 세그먼트 모듈 핀 연결 핀(a,b,c,d,e,f,g, dp) 제어  
  for(int j=0; j<8; j++){
    boolean on_off = bitRead(patterns[num], 7-j);
    digitalWrite(seg_pin[j], on_off);
  }
}

// 4자리 7세그먼트 표시 장치에 4자리 숫자 표시 함수
void show_4_digit(int n){
  
  n = n % 10000;		// 4자리로 제한
  int n4 = n / 1000;	// 천 자리
  n = n % 1000;
  int n3 = n / 100;		// 백 자리
  n = n % 100;
  int n2 = n / 10;		// 십 자리
  int n1 = n % 10;		// 한 자리

  show_digit(1, n4);
  delay(SEGMENT_DELAY);
  show_digit(2, n3);
  delay(SEGMENT_DELAY);
  show_digit(3, n2);
  delay(SEGMENT_DELAY);
  show_digit(4, n1);
  delay(SEGMENT_DELAY);
}

void loop()
{
  time_current = millis();
  
  if(time_current - time_previous >= 1000){
    time_previous = time_current;
    sec++;
    if(sec == 60){	// 60초가 될 경우 분 증가
      sec = 0;
      min++;
    }
    if(min == 60)	// 60분이 될 경우 초기화
      min = 0;
  }
  
  show_4_digit(min*100 + sec);
}

저작자표시 비영리 변경금지

티스토리툴바